How to enable Lightning Experience for all Profiles using Metadata

public with sharing class MetadataServiceUse {
   
    public static MetadataService.MetadataPort createService()
    {
        MetadataService.MetadataPort service = new MetadataService.MetadataPort();
        service.SessionHeader = new MetadataService.SessionHeader_element();
        service.SessionHeader.sessionId = UserInfo.getSessionId();
        return service;
    }
   
    public class MetadataServiceUseException extends Exception { }
   
    /**
     * Example helper method to interpret a SaveResult, throws an exception if errors are found
     **/
    public static void handleSaveResults(MetadataService.SaveResult saveResult)
    {
        // Nothing to see?
        if(saveResult==null || saveResult.success)
            return;
        // Construct error message and throw an exception
        if(saveResult.errors!=null)
        {
            List<String> messages = new List<String>();
            messages.add(
                (saveResult.errors.size()==1 ? 'Error ' : 'Errors ') +
                    'occured processing component ' + saveResult.fullName + '.');
            for(MetadataService.Error error : saveResult.errors)
                messages.add(
                    error.message + ' (' + error.statusCode + ').' +
                    ( error.fields!=null && error.fields.size()>0 ?
                        ' Fields ' + String.join(error.fields, ',') + '.' : '' ) );
            if(messages.size()>0)
                throw new MetadataServiceUseException (String.join(messages, ' '));
        }
        if(!saveResult.success)
            throw new MetadataServiceUseException ('Request failed with no specified error.');
    }
   
    /**
     * NOTE: Consider using Permission Sets, these can also be created and assignd with DML in Apex
     **/
    public static void updateLightningExperienceUserPermission(String fullName)
    {
        MetadataService.MetadataPort service = createService();
       
        MetadataService.Profile admin = new MetadataService.Profile();
        admin.fullName = fullName;
        admin.custom = false;
       
        MetadataService.ProfileUserPermission proUserPermission = new MetadataService.ProfileUserPermission();
        proUserPermission.name = 'LightningExperienceUser';
        proUserPermission.enabled = true;
       
        admin.userPermissions = new MetadataService.ProfileUserPermission[] {proUserPermission};
       
        List<MetadataService.SaveResult> results =
            service.updateMetadata(
                new MetadataService.Metadata[] { admin });
        handleSaveResults(results[0]);
    }
}